home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib08.dsk / BONDS BREAKEVEN.bas < prev    next >
BASIC Source File  |  2023-02-26  |  4KB  |  68 lines
  1. 1  REM  **********************
  2. 2  REM  * BONDS BREAKEVEN    *
  3. 3  REM  * BY CHRIS WILLIAMS  *
  4. 4  REM  * COPYRIGHT (C) 1982 *
  5. 5  REM  * BY MICRO-SPARC INC *
  6. 6  REM  * LINCOLN, MA. 01773 *
  7. 7  REM  **********************
  8. 55  REM 
  9. 56  REM  INTRODUCTION
  10. 57  REM 
  11. 60  HOME : PRINT "            MUNICIPAL BONDS--": PRINT "            BREAKEVEN"
  12. 80  PRINT : PRINT "  THIS PROGRAM WILL HELP YOU TO QUICKLY": PRINT : PRINT "DETERMINE HOW SMALL THE YIELD MUST BE": PRINT : PRINT "ON A TAX-FREE MUNICIPAL BOND IN ORDER": PRINT : PRINT "TO EQUAL WHATEVER TAXABLE RETURN YOU ARE"
  13. 85  PRINT "CURRENTLY EARNING."
  14. 100  PRINT : PRINT : PRINT "HIT ANY KEY TO CONTINUE": GET A$
  15. 110  HOME : VTAB 5: PRINT " WE ARE ASSUMING THE ALTERNATIVES ARE": PRINT : PRINT "IDENTICALLY RATED IN RISK (BY EITHER": PRINT : PRINT "MOODY'S OR STANDARD & POOR'S).": PRINT : PRINT "HIT ANY KEY TO CONTINUE": GET A$
  16. 119  REM 
  17. 120  REM  BEGIN INFO ACQUISITION
  18. 121  REM 
  19. 130  HOME : VTAB 5: PRINT "OKAY, YOU NEED TO INPUT SOME INFORMATION": PRINT 
  20. 140  PRINT "HOW DO YOU FILE YOUR TAX RETURNS?": PRINT : PRINT "IS IT SINGLE(S),MARRIED-JOINTLY(MJ),": PRINT : PRINT "MARRIED-SEPARATELY(MS),OR HEAD": PRINT : INPUT "OF HOUSEHOLD(HH)";B$
  21. 150  PRINT : PRINT "OKAY, AND WHAT IS YOUR ANNUAL": PRINT : INPUT "INCOME (IF = > 50000, SEE ARTICLE)?";INC
  22. 152  IF INC <50000  THEN  GOTO 160
  23. 155  PRINT  CHR$(7): PRINT : PRINT "ERROR": GOTO 150
  24. 160  HOME : PRINT "VERY WELL, NOW WHAT RETURN(%) ARE YOU": PRINT : PRINT "CURRENTLY GETTING ON YOUR MONEY?"
  25. 166  REM 
  26. 167  REM  NOTE NO CAP. GAINS ALLOWED
  27. 168  REM 
  28. 170  PRINT : PRINT "IT CAN BE FROM DIVIDENDS,SAVINGS": PRINT : PRINT "ACCOUNTS, OR ANYTHING TAXABLE (BUT NOT": PRINT : INPUT "CAPITAL GAINS.  -->";TR
  29. 175 IDX = 0
  30. 176  REM 
  31. 177  REM  INDEX ARRAYS
  32. 178  REM 
  33. 180  FOR IX = 10000 TO 50000  STEP 5000
  34. 190  IF INC <IX  THEN  GOTO 260
  35. 195 IDX = IDX +1
  36. 200  NEXT 
  37. 250  REM 
  38. 252  REM  STORE MARG. RATES
  39. 253  REM  FOR DIFFERENT
  40. 254  REM  FILING METHODS
  41. 255  REM 
  42. 260 S(1) = 12:S(2) = 15:S(3) = 16:S(4) = 19:S(5) = 21:S(6) = 24:S(7) = 27:S(8) = 27
  43. 270 MJ(1) = 10:MJ(2) = 12:MJ(3) = 14:MJ(4) = 16:MJ(5) = 18:MJ(6) = 21:MJ(7) = 22:MJ(8) = 25
  44. 280 MS(1) = 16:MS(2) = 17:MS(3) = 21:MS(4) = 24:MS(5) = 27:MS(6) = 27:MS(7) = 27:MS(8) = 30
  45. 290 HH(1) = 11:HH(2) = 12:HH(3) = 15:HH(4) = 18:HH(5) = 21:HH(6) = 22:HH(7) = 22:HH(8) = 26
  46. 300  IF B$ = "S"  THEN MARGN = S(IDX)
  47. 310  IF B$ = "MJ"  THEN MARGN = MJ(IDX)
  48. 320  IF B$ = "MS"  THEN MARGN = MS(IDX)
  49. 330  IF B$ = "HH"  THEN MARGN = HH(IDX)
  50. 340 MARGN = MARGN/50.
  51. 344  REM 
  52. 345  REM  COMPUTE REQ'D MUNIC. YIELD
  53. 346  REM 
  54. 350 MU = (1. -MARGN) *TR
  55. 354  REM 
  56. 355  REM  DISPLAY RESULTS
  57. 356  REM 
  58. 360  HOME : VTAB 5: PRINT "BECAUSE OF YOUR TAX LEVEL, YOUR BEFORE": PRINT : PRINT "TAX RETURN OF ";TR;"% IS ACTUALLY": PRINT : PRINT "ONLY ";MU;"%. YOU NEED FIND A TAX-FREE": PRINT : PRINT "RETURN OF ONLY THAT AMOUNT TO": PRINT : PRINT "BREAK EVEN."
  59. 370  IF MU >10  THEN  GOTO 400
  60. 380  PRINT : PRINT "****************************************": PRINT "YOU SHOULD BE ABLE TO FIND LOW RISK": PRINT : PRINT "MUNICIPALS YIELDING MORE THAN THAT.": PRINT "****************************************"
  61. 400  PRINT : PRINT "HIT ANY KEY TO CONTINUE": GET A$
  62. 404  REM 
  63. 405  REM  OPTION TO GO AGAIN
  64. 406  REM 
  65. 410  HOME : VTAB 4: PRINT "YOU CAN GO BACK NOW AND SEE HOW IT": PRINT : PRINT "LOOKS FOR OTHER INCOME LEVELS OR": PRINT : PRINT "FILING STATUSES -- OR OF COURSE, YOU": PRINT : PRINT "CAN EXIT.": PRINT : PRINT 
  66. 415  PRINT "HIT "; CHR$(34);"Q"; CHR$(34);" TO QUIT, OR ANYTHING": PRINT : PRINT "ELSE TO GO BACK."
  67. 420  PRINT : PRINT : GET C$: IF C$ = "Q"  THEN  STOP 
  68. 430  GOTO 130